upgpkg: 2.0.0-1

Thanks to @felixonmars

.SRCINFO

@@ -0,0 +1,19 @@
+pkgbase = python-pygls
+	pkgdesc = Pythonic generic implementation of the Language Server Protocol
+	pkgver = 2.0.0
+	pkgrel = 1
+	url = https://github.com/openlawlibrary/pygls
+	arch = any
+	license = Apache-2.0
+	checkdepends = python-pytest-asyncio
+	makedepends = git
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-poetry-core
+	depends = python-attrs
+	depends = python-cattrs
+	depends = python-lsprotocol
+	source = git+https://github.com/openlawlibrary/pygls.git#tag=v2.0.0
+	b2sums = db43d6da778d53ca879bf702a04e0779ec66dd6994987677b38c19b0fd88ccb30f2bfd5a556c50a85bdae879e08c54ab4cf7d92d029d7aff4b270f039ae63290
+
+pkgname = python-pygls

.nvchecker.toml

@@ -0,0 +1,4 @@
+[python-pygls]
+source = "git"
+git = "https://github.com/openlawlibrary/pygls.git"
+prefix = "v"

PKGBUILD

@@ -1,32 +1,45 @@
-# Maintainer: Otreblan <otreblain@gmail.com>
+# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
+# Contributor: Otreblan <otreblain@gmail.com>
 
-_name=pygls
 pkgname=python-pygls
-pkgver=0.10.1
+_name=${pkgname#python-}
+pkgver=2.0.0
 pkgrel=1
 pkgdesc='Pythonic generic implementation of the Language Server Protocol'
-arch=('any')
+arch=(any)
 url=https://github.com/openlawlibrary/pygls
-license=('APACHE')
-depends=('python-psutil' 'python-pydantic' 'python-typeguard')
-makedepends=('python-setuptools')
-checkdepends=('python-mock' 'python-pytest' 'python-pytest-asyncio')
-source=("$url/archive/v$pkgver/$_name-$pkgver.tar.gz")
-b2sums=('01927d80f6ba961ab0f745be3c62d67683603203c7b94429c2420869d8d90c2b4aa8e02cf2e54a04feb26e4144f2423882086f6007afc4648decc39f0814ae13')
+license=(Apache-2.0)
+depends=(
+  python-attrs
+  python-cattrs
+  python-lsprotocol
+)
+makedepends=(
+  git
+  python-build
+  python-installer
+  python-poetry-core
+)
+checkdepends=(python-pytest-asyncio)
+source=("git+$url.git#tag=v$pkgver")
+b2sums=('db43d6da778d53ca879bf702a04e0779ec66dd6994987677b38c19b0fd88ccb30f2bfd5a556c50a85bdae879e08c54ab4cf7d92d029d7aff4b270f039ae63290')
 
 build() {
-  cd $_name-$pkgver
-  python setup.py build
+  cd "$_name"
+  python -m build --wheel --skip-dependency-check --no-isolation
 }
 
 check() {
-  cd $_name-$pkgver
-  pytest
+  cd "$_name"
+  PYTHONPATH="$PWD/$_name:$PYTHONPATH" pytest
 }
 
 package() {
-  cd $_name-$pkgver
-  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
-}
+  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+  install -d "$pkgdir"/usr/share/licenses/$pkgname
+  ln -s "$site_packages"/"$_name"-$pkgver.dist-info/licenses/LICENSE.txt \
+    "$pkgdir"/usr/share/licenses/$pkgname
 
-# vim:set ts=2 sw=2 et:
+  cd "$_name"
+  python -m installer --destdir="$pkgdir" dist/*.whl
+}