upgpkg: 2.0.0-1

Thanks to @felixonmars

.SRCINFO

@@ -0,0 +1,19 @@
+pkgbase = python-pygls
+	pkgdesc = Pythonic generic implementation of the Language Server Protocol
+	pkgver = 2.0.0
+	pkgrel = 1
+	url = https://github.com/openlawlibrary/pygls
+	arch = any
+	license = Apache-2.0
+	checkdepends = python-pytest-asyncio
+	makedepends = git
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-poetry-core
+	depends = python-attrs
+	depends = python-cattrs
+	depends = python-lsprotocol
+	source = git+https://github.com/openlawlibrary/pygls.git#tag=v2.0.0
+	b2sums = db43d6da778d53ca879bf702a04e0779ec66dd6994987677b38c19b0fd88ccb30f2bfd5a556c50a85bdae879e08c54ab4cf7d92d029d7aff4b270f039ae63290
+
+pkgname = python-pygls

.nvchecker.toml

@@ -0,0 +1,4 @@
+[python-pygls]
+source = "git"
+git = "https://github.com/openlawlibrary/pygls.git"
+prefix = "v"

PKGBUILD

@@ -1,40 +1,45 @@
 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
 # Contributor: Otreblan <otreblain@gmail.com>
 
-_name=pygls
 pkgname=python-pygls
-pkgver=0.13.0
+_name=${pkgname#python-}
+pkgver=2.0.0
 pkgrel=1
 pkgdesc='Pythonic generic implementation of the Language Server Protocol'
-arch=('any')
+arch=(any)
 url=https://github.com/openlawlibrary/pygls
-license=('APACHE')
-depends=('python-pydantic' 'python-typeguard')
-makedepends=('python-build' 'python-installer' 'python-setuptools-scm'
-             'python-toml' 'python-wheel')
-checkdepends=('python-mock' 'python-pytest' 'python-pytest-asyncio')
-source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
-sha256sums=('d76e44768d75805da26dfbaec187c6251450af4b7b1cc0b7eb3587e6e27e32a4')
-b2sums=('74b357add149d6fc6b3cb75136587c024b82989a5c6bcf88981f6e2f285e9d5b2014212757bb2526010f03278ac89b3d105755b8185eb61302992b309414dd97')
+license=(Apache-2.0)
+depends=(
+  python-attrs
+  python-cattrs
+  python-lsprotocol
+)
+makedepends=(
+  git
+  python-build
+  python-installer
+  python-poetry-core
+)
+checkdepends=(python-pytest-asyncio)
+source=("git+$url.git#tag=v$pkgver")
+b2sums=('db43d6da778d53ca879bf702a04e0779ec66dd6994987677b38c19b0fd88ccb30f2bfd5a556c50a85bdae879e08c54ab4cf7d92d029d7aff4b270f039ae63290')
 
 build() {
-  cd $_name-$pkgver
+  cd "$_name"
   python -m build --wheel --skip-dependency-check --no-isolation
 }
 
 check() {
-  cd $_name-$pkgver
-  pytest
+  cd "$_name"
+  PYTHONPATH="$PWD/$_name:$PYTHONPATH" pytest
 }
 
 package() {
-  cd $_name-$pkgver
-  python -m installer --destdir="$pkgdir" dist/*.whl
-  rm -r "$pkgdir"/usr/lib/site-packages
-
-  # Symlink license file
   local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
   install -d "$pkgdir"/usr/share/licenses/$pkgname
-  ln -s "$site_packages"/$_name-$pkgver.dist-info/LICENSE.txt \
-    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+  ln -s "$site_packages"/"$_name"-$pkgver.dist-info/licenses/LICENSE.txt \
+    "$pkgdir"/usr/share/licenses/$pkgname
+
+  cd "$_name"
+  python -m installer --destdir="$pkgdir" dist/*.whl
 }