upgpkg: 1.3.1-2: Rebuild for Python 3.12

Thanks to @felixonmars

.SRCINFO

@@ -0,0 +1,18 @@
+pkgbase = python-pygls
+	pkgdesc = Pythonic generic implementation of the Language Server Protocol
+	pkgver = 1.3.1
+	pkgrel = 2
+	url = https://github.com/openlawlibrary/pygls
+	arch = any
+	license = Apache-2.0
+	checkdepends = python-pytest-asyncio
+	makedepends = git
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-poetry-core
+	depends = python-cattrs
+	depends = python-lsprotocol
+	source = git+https://github.com/openlawlibrary/pygls.git#tag=v1.3.1
+	b2sums = c893198f1004256118acfa1bee3aefb87f98a34f2a634de7263d621e56673312a735e94ab8703135e7e43df21cde0a07946a9187c54878c2dcadd696fb8830e4
+
+pkgname = python-pygls

PKGBUILD

@@ -1,30 +1,37 @@
-# Maintainer: Otreblan <otreblain@gmail.com>
+# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
+# Contributor: Otreblan <otreblain@gmail.com>
 
-_name=pygls
 pkgname=python-pygls
-pkgver=0.9.1
-pkgrel=3
+_name=${pkgname#python-}
+pkgver=1.3.1
+pkgrel=2
 pkgdesc='Pythonic generic implementation of the Language Server Protocol'
 arch=('any')
 url=https://github.com/openlawlibrary/pygls
-license=('APACHE')
-depends=('python')
-makedepends=('python-setuptools')
-checkdepends=('python-mock' 'python-pytest' 'python-pytest-asyncio')
-source=("$url/archive/v$pkgver/$_name-v$pkgver.tar.gz")
-b2sums=('f723ce70d1d080c52266b9449c589b9aabf04c748793a67d775436fa326fbdd6fd63876061fb5bdad95434c832e4ee351e36483b2a8406ad7b4dd9bdc9a1c2d2')
+license=('Apache-2.0')
+depends=('python-cattrs' 'python-lsprotocol')
+makedepends=('git' 'python-build' 'python-installer' 'python-poetry-core')
+checkdepends=('python-pytest-asyncio')
+source=("git+$url.git#tag=v$pkgver")
+b2sums=('c893198f1004256118acfa1bee3aefb87f98a34f2a634de7263d621e56673312a735e94ab8703135e7e43df21cde0a07946a9187c54878c2dcadd696fb8830e4')
 
 build() {
-  cd $_name-$pkgver
-  python setup.py build
+  cd "$_name"
+  python -m build --wheel --skip-dependency-check --no-isolation
 }
 
 check() {
-  cd $_name-$pkgver
-  pytest
+  cd "$_name"
+  PYTHONPATH="$PWD/$_name:$PYTHONPATH" pytest
 }
 
 package() {
-  cd $_name-$pkgver
-  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  cd "$_name"
+  python -m installer --destdir="$pkgdir" dist/*.whl
+
+  # Symlink license file
+  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+  install -d "$pkgdir"/usr/share/licenses/$pkgname
+  ln -s "$site_packages"/"$_name"-$pkgver.dist-info/LICENSE.txt \
+    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
 }