upgpkg: 1.3.0-1

Thanks to @felixonmars

.SRCINFO

@@ -0,0 +1,18 @@
+pkgbase = python-pygls
+	pkgdesc = Pythonic generic implementation of the Language Server Protocol
+	pkgver = 1.3.0
+	pkgrel = 1
+	url = https://github.com/openlawlibrary/pygls
+	arch = any
+	license = Apache-2.0
+	checkdepends = python-pytest-asyncio
+	makedepends = git
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-poetry-core
+	depends = python-cattrs
+	depends = python-lsprotocol
+	source = git+https://github.com/openlawlibrary/pygls.git#tag=v1.3.0
+	b2sums = SKIP
+
+pkgname = python-pygls

PKGBUILD

@@ -1,40 +1,37 @@
 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
 # Contributor: Otreblan <otreblain@gmail.com>
 
-_name=pygls
 pkgname=python-pygls
-pkgver=1.0.1
+_name=${pkgname#python-}
+pkgver=1.3.0
 pkgrel=1
 pkgdesc='Pythonic generic implementation of the Language Server Protocol'
 arch=('any')
 url=https://github.com/openlawlibrary/pygls
-license=('APACHE')
-depends=('python-lsprotocol' 'python-typeguard')
-makedepends=('python-build' 'python-installer' 'python-setuptools-scm'
-             'python-toml' 'python-wheel')
-checkdepends=('python-mock' 'python-pytest' 'python-pytest-asyncio')
-source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
-sha256sums=('f3ee98ddbb4690eb5c755bc32ba7e129607f14cbd313575f33d0cea443b78cb2')
-b2sums=('62089e817214d8ae0b9d2454a0787e18f077183fbcd1dcf538630ec167f1356f3031dff679dd45aeab48a11e545b7c63fa74e1c42fca7fec7c33d51b72efb25f')
+license=('Apache-2.0')
+depends=('python-cattrs' 'python-lsprotocol')
+makedepends=('git' 'python-build' 'python-installer' 'python-poetry-core')
+checkdepends=('python-pytest-asyncio')
+source=("git+$url.git#tag=v$pkgver")
+b2sums=('SKIP')
 
 build() {
-  cd $_name-$pkgver
+  cd "$_name"
   python -m build --wheel --skip-dependency-check --no-isolation
 }
 
 check() {
-  cd $_name-$pkgver
-  pytest
+  cd "$_name"
+  PYTHONPATH="$PWD/$_name:$PYTHONPATH" pytest
 }
 
 package() {
-  cd $_name-$pkgver
+  cd "$_name"
   python -m installer --destdir="$pkgdir" dist/*.whl
-  rm -r "$pkgdir"/usr/lib/site-packages
 
   # Symlink license file
   local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
   install -d "$pkgdir"/usr/share/licenses/$pkgname
-  ln -s "$site_packages"/$_name-$pkgver.dist-info/LICENSE.txt \
+  ln -s "$site_packages"/"$_name"-$pkgver.dist-info/LICENSE.txt \
     "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
 }